Formula Kompatibel Datedif untuk OpenOffice.org Calc

January 30, 2006

Pada OpenOffice.org Calc, fungsi Datedif yang biasanya digunakan pada Microsoft Excel untuk menghitung perbedaan hari, bulan atau tahun antara dua tanggal tidak dapat digunakan. Sebenarnya, fungsi Datedif sendiri bukan asli dari Microsoft Excel. Ketersediaannya hanya untuk kompatibilitas dengan Lotus 1-2-3. Meskipun pada OpenOffice.org Calc tidak tersedia fungsi ini, tetapi OpenOffice.org Calc mempunyai fungsi days(), months() dan years() yang tidak tersedia pada Microsoft Excel. Dengan fungsi-fungsi ini, kita dapat membuat formula yang kompatibel dengan fungsi Datedif.

Sebagai contoh, misalnya kita mempunyai data tanggal awal pada cell A1 dan data tanggal akhir pada A2.

Selisih Tahun
Microsoft Excel: =DATEDIF(A1;A2;"Y")
OpenOffice.org Calc: =YEARS(A1;A2;0)

Selisih Bulan
Microsoft Excel: =DATEDIF(A1;A2;"M")
OpenOffice.org Calc: =MONTHS(A1;A2;0)

Selisih Hari
Microsoft Excel: =DATEDIF(A1;A2;"D")
OpenOffice.org Calc: =DAYS(A2;A1)

Selisih Hari dengan Mengabaikan Tahun dan Bulannya
Microsoft Excel: =DATEDIF(A1;A2;"MD")
OpenOffice.org Calc:

PLAIN TEXT

CODE:

=IF(DAY(A1)>DAY(A2);DAYS(A2;DATE(YEAR(A2);MONTH(A2)-1;DAY(A1)));DAYS(A2;DATE(YEAR(A2);MONTH(A2);DAY(A1))))

Selisih Bulan dengan Mengabaikan Tahun dan Tanggalnya
Microsoft Excel: =DATEDIF(A1;A2;"YM")
OpenOffice.org Calc:

PLAIN TEXT

CODE:

=MONTHS(A1;A2;0)-(YEARS(A1;A2;0)*12)

Selisih Hari dengan Mengabaikan Tahunnya
Microsoft Excel: =DATEDIF(A1;A2;"YD")
OpenOffice.org Calc:

PLAIN TEXT

CODE:

=IF(OR(MONTH(A1)>MONTH(A2);AND(MONTH(A1)=MONTH(A2);DAY(A1)>DAY(A2)));DAYS(A2;DATE(YEAR(A2)-1;MONTH(A1);DAY(A1)));DAYS(A2;DATE(YEAR(A2);MONTH(A1);DAY(A1))))

Category Posted in MS Office, Open Office

Tulisan lain yang mungkin terkait dengan tulisan di atas:

5 Responses to “Formula Kompatibel Datedif untuk OpenOffice.org Calc”

foxy said on January 31, 2006, 7:05 pm:

Nah gitu dong sering2 kasih tips buat OpenOffice, soalnya di kantor banyak yg nanya tuh

ID said on February 1, 2006, 11:26 am:

Tips bagus saya juga pengguna setia OpenOffice sejak masih buatan Jerman

Kok Wee said on September 5, 2006, 1:02 pm:

Thank you very much for these formula! I’ve been searching the net for alternative formula for excel DATEDIF in OpenOffice for many days… Finally came upon your page. Though i don’t understand Bahasa Indonesia the formula are still the same. Nice Work! Thank you once again!

Cheers!

james said on October 7, 2006, 7:23 pm:

I stumbled across this page when looking for an equivalent function in Open Office Calc to determine the number of days left in the year (2006). i used:
=DAYS("31/12/2006";TODAY())

Kharaja said on May 23, 2007, 6:18 pm:

Mas-mas, mbak-mbak,

Mau tanya sekalian. Di open Office aku udah bisa pakai DAYS. Udah oke. Begitu di save aku tutup itu file. Eh, begitu di buka jadi nya tampilan #MACRO? semuanya?

Rumus tetap tapi hasil jadi #MACRO? Mengapa yah? makasih buat sharingnya

All fields marked with "*" are required.